Персоналізація панелі навігації Провідника файлів
У Провіднику файлів деякі елементи, такі як “Цей комп’ютер”, закріплені на панелі навігації за замовчуванням. Розгортаючи “Цей комп’ютер”, ви отримуєте доступ до бібліотек Windows та розділів жорсткого диска. Якщо ви хочете додати інші елементи на цю панель, можна скористатися розділом “Швидкий доступ”, де можна закріплювати диски та папки. Проте, якщо ваша мета – закріпити диски як окремі елементи безпосередньо на панелі навігації, а не в підрозділах “Цей комп’ютер” або “Швидкий доступ”, це теж можливо. Для реалізації цього підходу знадобиться пакетний скрипт.
Скрипт, створений користувачем JosefZ з Superuser, дозволяє закріпити диски C та D на панелі навігації Провідника файлів. Цей скрипт можна модифікувати для закріплення інших дисків за вашим бажанням.
Створення резервної копії ключа реєстру
Перед застосуванням скрипта важливо створити резервну копію ключа реєстру. Для цього відкрийте редактор реєстру Windows (regedit.exe) і перейдіть до наступного розділу:
HKEY_CURRENT_USER\Software\Microsoft\Windows\CurrentVersion\Explorer\HideDesktopIcons\NewStartPanel
Клацніть правою кнопкою миші на ключ “NewStartPanel” і виберіть “Експорт”, зберігаючи його у безпечному місці. Це запобіжний захід, який необхідно виконати для забезпечення безпеки.
Інструкція зі закріплення диска на панелі навігації
Відкрийте програму “Блокнот” та скопіюйте наступний код. Збережіть файл з будь-якою назвою, але з розширенням .bat.
@ECHO OFF
SETLOCAL EnableExtensions
set "_icon=%%SystemRoot%%system32\imageres.dll,27"
set "_name=D DataDisk"
set "_guid=ffffffff-ffff-ffff-0000-00000000000d"
set "_target=d:"
set "_regK=HKCU\Software\Classes\CLSID"
set "_regE=HKCU\Software\Microsoft\Windows\CurrentVersion\Explorer"
if NOT "%~1"=="" goto :deleAll
reg add %_regK%\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regK%\{%_guid%}\DefaultIcon /ve /t REG_EXPAND_SZ /d %_icon% /f
reg add %_regK%\{%_guid%} /v System.IsPinnedToNameSpaceTree /t REG_DWORD /d 0x1 /f
reg add %_regK%\{%_guid%} /v SortOrderIndex /t REG_DWORD /d 0x42 /f
reg add %_regK%\{%_guid%}\InProcServer32 /ve /t REG_EXPAND_SZ /d %%systemroot%%\system32\shell32.dll /f
reg add %_regK%\{%_guid%}\Instance /v CLSID /t REG_SZ /d {0E5AAE11-A475-4c5b-AB00-C66DE400274E} /f
reg add %_regK%\{%_guid%}\InstanceInitPropertyBag /v Attributes /t REG_DWORD /d 0x11 /f
reg add %_regK%\{%_guid%}\InstanceInitPropertyBag /v TargetFolderPath /t REG_EXPAND_SZ /d "%_target%" /f
reg add %_regK%\{%_guid%}\ShellFolder /v FolderValueFlags /t REG_DWORD /d 0x28 /f
reg add %_regK%\{%_guid%}\ShellFolder /v Attributes /t REG_DWORD /d 0xF080004D /f
reg add %_regE%\DesktopNameSpace\{%_guid%} /ve /t REG_SZ /d "%_name%" /f
reg add %_regE%\HideDesktopIcons\NewStartPanel /v "{%_guid%}" /t REG_DWORD /d 0x1 /f
:endlocal
ENDLOCAL
goto :eof
:deleAll
reg delete %_regK%\{%_guid%} /f
reg delete %_regE%\DesktopNameSpace\{%_guid%} /f
reg delete %_regE%\HideDesktopIcons\NewStartPanel /v "{%_guid%}" /f
goto :endlocal
Після збереження файлу, клацніть по ньому правою кнопкою миші та виберіть “Запустити від імені адміністратора”. Цей скрипт додасть диск D на панель навігації Провідника файлів.
Для додавання диску C, вам необхідно модифікувати попередній скрипт. Змініть рядки 3-6 на наступні:
set "_icon=%%SystemRoot%%\system32\imageres.dll,31" set "_name=c SystemDisk" set "_guid=ffffffff-ffff-ffff-0000-00000000000c" set "_target=c:"
Зіставивши два набори рядків, ви зрозумієте принцип зміни скрипта для закріплення будь-якого іншого диску за вашим вибором.
Для видалення закріпленого диску відкрийте командний рядок від імені адміністратора, перейдіть до папки, де зберігається ваш скрипт, і виконайте команду, замінивши “name-of-script.bat” на ім’я вашого файлу:
name-of-script.bat x
Цю операцію потрібно виконати для кожного диска, який був закріплений на панелі навігації. Якщо в процесі виникають проблеми, відновіть ключ реєстру з резервної копії.