З кожним випуском нового функціонального оновлення для Windows 10, інструмент для створення медіа, що використовується для завантаження Windows 10, також зазнає оновлення. Нова версія цього інструменту дозволяє користувачам отримати актуальну, найновішу версію Windows 10. Таким чином, якщо ви шукаєте можливість завантажити та встановити старіші оновлення, інструмент створення медіа з офіційного веб-сайту Microsoft не буде вам корисним. Однак, ISO-образи старих версій все ще доступні, і за допомогою невеликого BAT-файлу ви можете завантажити будь-яку збірку Windows 10 через цей інструмент.
СПОЙЛЕР: прокрутіть сторінку вниз, щоб переглянути відеоінструкцію в кінці цієї статті.
Завантаження будь-якої збірки Windows 10
Цей BAT-файл створив користувач Reddit під ніком aveyo. Ви можете завантажити його безпосередньо за посиланням на Pastebin, але ми також наведемо скрипт тут, на випадок, якщо посилання стане неактивним.
Відкрийте програму “Блокнот” та скопіюйте в неї наступний код. Збережіть файл із розширенням BAT.
@echo off &title MediaCreationTool.bat by AveYo
:: Універсальна оболонка для всіх версій "RedStone": 1607, 1703, 1709, 1803 та 1809
:: Використовує лише оригінальні файли Microsoft для поточних та попередніх випусків Windows 10 MCT
:: Повна підтримка створення бізнес-каналу (Enterprise) з користувацькою мовою, x86, x64 або AIO!
:: Додайте/видаліть параметри запуску нижче, якщо потрібно - він попередньо налаштований для найменшої кількості проблем під час оновлень
set "OPTIONS=/Telemetry Disable /DynamicUpdate Disable /MigrateDrivers all /ResizeRecoveryPartition disable /ShowOOBE none"
:: Розкоментуйте для показу журналу консолі mct у реальному часі для налагодження
rem set "OPTIONS=%OPTIONS% /Console"
:: Розкоментуйте, щоб обійти діалогове вікно gui та жорстко закодувати цільову версію: 1=1607, 2=1703, 3=1709, 4=1803, 5=1809
rem set/a MCT_VERSION=5
:: Доступні версії MCT
set versions= 1607 [ RedStone 1 ], 1703 [ RedStone 2 ], 1709 [ RedStone 3 ], 1803 [ RedStone 4 ], 1809 [ RedStone 5 ]
:: Показує діалогове вікно %1:заголовок %2:заголовок %3:варіанти %4:вихідна_змінна
if not defined MCT_VERSION call :choice "MediaCreationTool.bat by AveYo" "Виберіть версію Windows 10" "%versions%" MCT_VERSION
if not defined MCT_VERSION echo Не вибрано MCT_VERSION, вихід.. & timeout /t 5 & exit/b
goto version%MCT_VERSION%
:version1 1607 [RS1]
set "V=1607"
set "D=20170116"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod/Products_20170116.cab"
set "MCT=https://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Версія %V% %D% вибрана!
goto process
:version2 1703 [RS2]
set "V=1703"
set "D=20170317"
set "EULA=https://wscont.apps.microsoft.com/winstore/OSUpgradeNotification/MediaCreationTool/prod"
set "EULA_FIX=https://download.microsoft.com/download/C/0/3/C036B882-9F99-4BC9-A4B5-69370C4E17E9"
set "CAB=https://download.microsoft.com/download/9/5/4/954415FD-D9D7-4E1F-8161-41B3A4E03D5E/products_20170317.cab"
set "MCT=https://download.microsoft.com/download/1/C/4/1C41BC6B-F8AB-403B-B04E-C96ED6047488/MediaCreationTool.exe"
:: 1703 MCT також має помилки, тому використовуйте 1607
set "MCT=https://download.microsoft.com/download/C/F/9/CF9862F9-3D22-4811-99E7-68CE3327DAE6/MediaCreationTool.exe"
echo Версія %V% %D% вибрана!
goto process
:version3 1709 [RS3]
set "V=1709"
set "D=20180105"
set "EULA="
set "CAB=https://download.microsoft.com/download/3/2/3/323D0F94-95D2-47DE-BB83-1D4AC3331190/products_20180105.cab"
set "MCT=https://download.microsoft.com/download/A/B/E/ABEE70FE-7DE8-472A-8893-5F69947DE0B1/MediaCreationTool.exe"
echo Версія %V% %D% вибрана!
goto process
:version4 1803 [RS4]
set "V=1803"
set "D=20180420"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/2/6/626729CF-8C1C-43DF-8C9C-AD2FD56948C3/products_20180420.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1803.exe"
echo Версія %V% %D% вибрана!
goto process
:version5 1809 [RS5]
set "V=1809"
set "D=20180924"
set "EULA="
set "CAB=https://download.microsoft.com/download/6/F/B/6FB97F08-E010-48A4-A9DC-18FCA920CEB4/products_20180924.cab"
set "MCT=https://software-download.microsoft.com/download/pr/MediaCreationTool1809.exe"
echo Версія %V% %D% вибрана!
goto process
:process
echo.
echo Примітка: MCT залежить від служби BITS! Якщо виникають проблеми, запустіть скрипт як адміністратор.
bitsadmin.exe /reset /allusers 2>nul
net stop bits /y 2>nul
net start bits /y 2>nul
:: очищення - може включати тимчасові файли, але не рекомендується, оскільки неможливо відновити через C:$Windows.~WSSourcessetuphost
pushd "%~dp0"
del /f /q products.* 2>nul &rem rd /s/q C:$Windows.~WS 2>nul & rd /s/q C:$WINDOWS.~BT 2>nul
:: завантажити MCT
set "WEBCLIENT=[Net.ServicePointManager]::SecurityProtocol="tls12,tls11,tls";(new-object System.Net.WebClient)"
if not exist MediaCreationTool%V%.exe powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%MCT%','MediaCreationTool%V%.exe');"
if not exist MediaCreationTool%V%.exe color 0c & echo Помилка! відсутній MediaCreationTool%V%.exe & pause & exit /b
:: завантажити CAB
if not exist products_%D%.cab powershell -noprofile -c "%WEBCLIENT%.DownloadFile('%CAB%','products_%D%.cab');"
if not exist products_%D%.cab color 0c & echo Помилка! відсутній products_%D%.cab & pause & exit /b
:: розпакувати CAB
expand.exe -R products_%D%.cab -F:* . >nul 2>nul
if not exist products.xml color 0c & echo Помилка! поганий або відсутній products_%D%.cab & pause & exit /b
:: патч XML, щоб дозволити вибирати бізнес-канали (Enterprise) і незначні косметичні виправлення
set "READ_XML=$f=[System.IO.File]::ReadAllText('products.xml')"
set "WRITE_XML=[System.IO.File]::WriteAllText('products.xml', $f)"
set "r1= $f=$f.Replace('IsRetailOnly>True<','IsRetailOnly>False<')"
set "r2=.Replace('%%ENTERPRISE','Windows 10 Enterprise')"
:: виправити старі посилання EULA, що ламають MCT в 1607 і 1703
if not defined EULA (set "r3=") else set "r3=.Replace('%EULA%','%EULA_FIX%')"
powershell -c "%READ_XML%; %r1%%r2%%r3%; %WRITE_XML%;"
:: запакувати XML назад у CAB
start "" /wait makecab products.xml products.cab
:: нарешті, запустіть MCT з локальною конфігурацією та додатковими параметрами запуску
start "" MediaCreationTool%V%.exe /Selfhost %OPTIONS%
exit/b
:: утиліти
::------------------------------------------------------------------------------------------------------------------------------
:choice %1:title %2:header %3:choices %4:output_variable [GUI радіокнопки діалоговий фрагмент від AveYo] випущений під ліцензією MIT
setlocal &set "parameters=$title="%~1"; $header="%~2"; $choices="%~3"; $global:c="";"
set "s1=[void][System.Reflection.Assembly]::LoadWithPartialName('System.Windows.Forms');$f=New-Object System.Windows.Forms.Form"
set "s2=;$f.Text=$title; $f.Forecolor="Snow"; $f.BackColor=0xff180052; $f.StartPosition='CenterScreen'; $f.AutoSize=$true;"
set "s3=$g=New-Object System.Windows.Forms.GroupBox; $g.Location='40,10'; $g.Margin='0,0,40,0'; $g.MinimumSize="280,100";"
set "s4=$g.AutoSize=$true; $g.text=$header; $f.Controls.Add($g);"
set "s5=$i=1; foreach($l in $choices.split(',')){ $r=New-Object System.Windows.Forms.RadioButton; $r.Location='20,'+(30*$i);"
set "s6=$r.Name=$i;$r.Text=$l;$r.AutoSize=$true;$r.add_Click({$global:c=$this.Name}); $g.Controls.Add($r); $r.Checked=1; $i++};"
set "s7=$j=1;foreach($t in @('OK','Вихід')){$b=New-Object System.Windows.Forms.Button;$b.Location=''+(120*($j-1)+80)+','+40*$i;"
set "s8=$b.Name="b"+$j; $b.Text=$t; $b.DialogResult=$j; if ($j -eq 1){$f.AcceptButton=$b}; $f.Controls.Add($b); $j++};"
set "s9=$f.Add_Shown({$f.Activate()}); $ret=$f.ShowDialog(); if ($ret -eq 2){$global:c=""}; write-host $global:c"
for /l %%# in (1,1,9) do call set "ps_Choice=%%ps_Choice%%%%s%%#:"="%%"
for /f "usebackq tokens=* delims=" %%# in (`powershell -noprofile -c "%parameters% %ps_Choice%"`) do set "output_var=%%#"
endlocal & set "%~4=%output_var%" & exit/b
::------------------------------------------------------------------------------------------------------------------------------
Запустіть цей BAT-файл з правами адміністратора. З’явиться вікно командного рядка, а потім інше вікно із запитом, яку версію Windows 10 ви хочете завантажити. Ви можете завантажити фінальні збірки Redstone з 1 по 5.
Після того, як ви оберете потрібну збірку, інструмент створення медіа завантажиться в ту ж папку, де був збережений BAT-файл. Тепер ви можете запустити інструмент і використати його для завантаження вибраної збірки Windows 10. Інструмент дасть вам змогу оновити поточну інсталяцію або створити завантажувальний USB-накопичувач.
Усі файли завантажуються безпосередньо з серверів Microsoft. Цей BAT-файл лише допомагає вам знайти необхідний файл та ініціювати завантаження. Він не надає файли самостійно і не вносить змін до файлів, наданих Microsoft.