Якщо ваш Інтернет працює, і вам потрібно відстежувати, чи є у вас з’єднання чи ні, найпростіший спосіб зробити це – стежити за символом Wi-Fi у системній панелі Windows 10. Коли ви втратите з’єднання з Інтернетом, на символі WiFi з’являється жовтий знак оклику. Ви також можете пінгувати веб-сайт. Якщо ви не можете стежити за системним треєм, а пінг здається вам утомливим, ви можете налаштувати звукові сповіщення про підключення до Інтернету в Windows 10 за допомогою простого сценарію.
ПОВІДОМЛЕННЯ СПОЙЛЕРА: прокрутіть униз і перегляньте відеоурок у кінці цієї статті.
Сповіщення про підключення до Інтернету
Цей сценарій спочатку був написаний суперкористувачем Фаббі, а вдосконалено VMMF. Сценарій вимагає завантажити безкоштовну утиліту під назвою Утиліти GNU для Win32. Розпакуйте його та знайдіть у наступній папці EXE під назвою Sleep.exe.
UnxUtilsusrlocalwbin
Це буде використано для додавання часу очікування між перевірками. Цей EXE має бути в тій самій папці, в якій ви зберігаєте сценарій. Вам більше нічого не потрібно, тому не соромтеся видалити його.
Відкрийте Блокнот і вставте в нього наступне. Збережіть його з розширенням CMD і запустіть файл. Файл sound.vbs буде створений сценарієм, тому не турбуйтеся про це.
@ECHO OFF
:whileNoInternet
set "host=8.8.8.8"
::check if internet is working
PING -n 1 -w 5000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% neq 0 (
::the internet is not working keep cheking until it does
echo No internet yet %TIME%
GOTO whileNoInternet
)
echo we gained internet
::the internet is working play internet ON song
@echo off
set "file=InternetON_GOGOGO.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
@ECHO OFF
:whileInternet
sleep.exe 5s
::check if internet is still working
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: detect possible internet glitches (do not trust the first failure)
echo internet glitch detected
sleep.exe 10s
PING -n 1 -w 1000 "%host%" | findstr /r /c:"[0-9] *ms"
if %errorlevel% == 0 (
::the internet is still working keep cheking until it does not
echo We have internet %TIME%
GOTO whileInternet
)
:: if it failed twice in a row most likely internet is down
echo we lost internet
::the internet is not working anymore, play internet OFF song
@echo off
set "file=InternetHasFallen.mp3"
( echo Set Sound = CreateObject("WMPlayer.OCX.7"^)
echo Sound.URL = "%file%"
echo Sound.Controls.play
echo do while Sound.currentmedia.duration = 0
echo wscript.sleep 100
echo loop
echo wscript.sleep (int(Sound.currentmedia.duration^)+1^)*1000) >sound.vbs
start /min sound.vbs
::start monitoring if it comes back
GOTO whileNoInternet
Це все, що вам потрібно зробити. Вікно командного рядка залишиться відкритим, перевіряючи стан вашого підключення до Інтернету. Якщо він зміниться, ви почуєте звук вимкнення.